code.consxy.com Git - clnl/blob - src/test/main.lisp

   1 (in-package #:clnl-test)
   2
   3 (defparameter *tests* nil)
   4
   5 (defun run-and-print-test (test)
   6  (let
   7   ((green (format nil "~c[1;32m" #\Esc))
   8    (red (format nil "~c[1;31m" #\Esc))
   9    (result (funcall (cadr test))))
  10   (format t "~A- ~S ~A~c[0m~%" (if result green red) (car test) (if result "passed" "failed") #\Esc)
  11   result))
  12
  13 (defun run-tests (tests)
  14  (let
  15   ((final-result t))
  16   (loop
  17    :for test :in tests
  18    :for result := (run-and-print-test test)
  19    :do (setf final-result (and final-result result)))
  20   final-result))
  21
  22 (defun run-all-tests ()
  23  (run-tests (reverse *tests*)))
  24
  25 (defun run-tests-matching (match)
  26  (run-tests
  27   (remove-if-not (lambda (test-name) (cl-ppcre:scan (format nil "^~A$" match) test-name)) *tests* :key #'car)))
  28
  29 (defun find-test (name)
  30  (or
  31   (find name *tests* :test #'string= :key #'car)
  32   (error "Couldn't find test with name: ~A" name)))
  33
  34 (defun test-debug (name) (format t "----~%~A~%" (funcall (third (find-test name)))))
  35 (defun test-scala-prog (name) (format t "----~%~A~%" (fourth (find-test name))))
  36 (defun test-scala-input (name) (format t "----~%~A~%" (fifth (find-test name))))
  37
  38 (defmacro defsimpletest (name test-fn debug-fn scala-prog scala-input)
  39  `(progn
  40    ;(when (find-test ,name) (error "Test with name ~S already exists, abort, abort" ,name))
  41    (push
  42     (list ,name ,test-fn ,debug-fn ,scala-prog ,scala-input)
  43     *tests*)))
  44
  45 (defun checksum= (expected got)
  46  (if (stringp expected)
  47   (string= got expected)
  48   (find got expected :test #'string=)))
  49
  50 ; To be used only with the simplest of tests, just a list of commands and a checksum of the
  51 ; world after they've been run.
  52 (defmacro defsimplecommandtest (name commands checksum)
  53  `(defsimpletest
  54    (format nil "Simple Command - ~A" ,name)
  55    (lambda ()
  56     (clnl:boot)
  57     (clnl:run-commands ,commands)
  58     (checksum= ,checksum (checksum-world)))
  59    (lambda ()
  60     (clnl:boot)
  61     (clnl:run-commands ,commands)
  62     (format nil "~A~A"
  63      (clnl-nvm:export-world)
  64      (checksum-world)))
  65    "bin/runcmd.scala"
  66    (format nil "~A~%" ,commands)))
  67
  68 (defmacro defsimplereportertest (name reporter value checksum)
  69  `(defsimpletest
  70    (format nil "Simple Reporter - ~A" ,name)
  71    (lambda ()
  72     (clnl:boot)
  73     (and
  74      (string= (funcall (intern "DUMP-OBJECT" :clnl-nvm) (clnl:run-reporter ,reporter)) ,value)
  75      (checksum= ,checksum (checksum-world))))
  76    (lambda ()
  77     (clnl:boot)
  78     (format nil "~A~%~A~A"
  79      (funcall (intern "DUMP-OBJECT" :clnl-nvm) (clnl:run-reporter ,reporter))
  80      (clnl-nvm:export-world)
  81      (checksum-world)))
  82    "bin/runreporter.scala"
  83    (format nil "~A~%" ,reporter)))
  84
  85 (defmacro defviewtest (name commands checksum)
  86  `(defsimpletest
  87    (format nil "Simple View - ~A" ,name)
  88    (lambda ()
  89     (clnl:boot)
  90     (clnl:run-commands ,commands)
  91     (let
  92      ((viewsum (checksum-view)))
  93      (when (not (checksum= ,checksum viewsum))
  94       (format t "~c[1;35m-- For ~A, got ~A but expected ~A~c[0m~%" #\Esc ,name viewsum ,checksum #\Esc))
  95      (checksum= ,checksum (checksum-view))))
  96    (lambda ()
  97     (clnl:boot)
  98     (clnl:run-commands ,commands)
  99     (save-view-to-ppm)
 100     (format nil "~A" (checksum-view)))
 101    ""
 102    (format nil "~A~%" ,commands)))
 103
 104 (defun checksum-world ()
 105  (format nil "~{~2,'0X~}"
 106   (map 'list #'identity
 107    (ironclad:digest-sequence
 108     :sha1
 109     (map '(vector (unsigned-byte 8)) #'char-code (clnl-nvm:export-world))))))
 110
 111 (defun checksum-view ()
 112  (format nil "~{~2,'0X~}"
 113   (map 'list #'identity
 114    (ironclad:digest-sequence :sha1 (coerce (clnl-interface:export-view) '(vector (unsigned-byte 8)))))))
 115
 116 (defun save-view-to-ppm ()
 117  (let
 118   ((height 143) (width 143)) ; hardcoded in interface, hardcoded here, cry for me
 119   (with-open-file (str "cl.ppm"
 120                    :direction :output
 121                    :if-exists :supersede
 122                    :if-does-not-exist :create
 123                    :element-type '(unsigned-byte 8))
 124    (write-sequence (map 'vector #'char-code (format nil "P6~%")) str)
 125    (write-sequence (map 'vector #'char-code (format nil "143 143~%")) str)
 126    (write-sequence (map 'vector #'char-code (format nil "255~%")) str)
 127    (let
 128     ((image-data (clnl-interface:export-view)))
 129     (dotimes (i width)
 130      (dotimes (j height)
 131       (write-byte (aref image-data (+ 0 (* 4 (+ (* (- (1- height) i) width) j)))) str)
 132       (write-byte (aref image-data (+ 1 (* 4 (+ (* (- (1- height) i) width) j)))) str)
 133       (write-byte (aref image-data (+ 2 (* 4 (+ (* (- (1- height) i) width) j)))) str)))))))
 134
 135 (defun run ()
 136  (loop
 137   :for str := (progn (format t "> ") (force-output) (read-line))
 138   :while str
 139   :do (progn (asdf:load-system :clnl-test) (run-tests-matching str))))