code.consxy.com Git - clnl/blob - src/main/main.lisp

   1 (in-package #:clnl)
   2
   3 (defun e (ast) ast)
   4
   5 (defun r (str)
   6  (let*
   7   ((lexed-ast (let ((ast (clnl-lexer:lex str)))
   8                (format t "Via lexing, AST for~%~S~% became~%~S~%~%" str ast) ast))
   9    (parsed-ast (let ((ast (clnl-parser:parse lexed-ast)))
  10                 (format t "Via parsing, AST for~%~S~% became~%~S~%~%" lexed-ast ast) ast))
  11    (transpiled-ast (let ((ast (clnl-transpiler:transpile parsed-ast)))
  12                     (format t "Via transpiling, AST for~%~S~% became~%~S~%" parsed-ast ast) ast)))
  13   (eval transpiled-ast)))
  14
  15 (defun p (result) result)
  16
  17 (defun run ()
  18  "RUN => RESULT
  19
  20 ARGUMENTS AND VALUES:
  21
  22   RESULT: undefined, the system terminates at the end of the loop
  23
  24 DESCRIPTION:
  25
  26   RUN starts up the CLNL system."
  27
  28  (boot)
  29  (sb-thread:make-thread #'clnl-cli:run)
  30  (clnl-interface:run))
  31
  32 (defun boot (&optional file headless-mode)
  33  "BOOT &optional FILE HEADLESS-MODE => RESULT
  34
  35 ARGUMENTS AND VALUES:
  36
  37   FILE: nlogo file with which to initialize state
  38   HEADLESS-MODE: a boolean, defaults to nil
  39   RESULT: undefined
  40
  41 DESCRIPTION:
  42
  43   BOOT does exactly that, boots the clnl system in a clean state.  The seed
  44   is set so that multiple runs will evaluate to the same.
  45
  46   When FILE is not provided, a default model is used.
  47
  48   When HEADLESS-MODE is set to nil, the opengl interface is initialized.
  49   Otherwise, the model will run headlessly, with no view."
  50  (let
  51   ((netlogoed-lisp
  52     (model->single-form-lisp
  53      (if file (with-open-file (str file) (clnl-model:read-from-nlogo str)) (clnl-model:default-model))
  54      :initialize-interface (not headless-mode)))
  55    (*package* *model-package*))
  56   (eval netlogoed-lisp)))
  57
  58 (defun run-commands (cmds)
  59  "RUN-COMMANDS CMDS => RESULT
  60
  61 ARGUMENTS AND VALUES:
  62
  63   CMDS: A string that may have one more NetLogo commands
  64   RESULT: undefined
  65
  66 DESCRIPTION:
  67
  68   RUN-COMMANDS will take NetLogo commands, put them through the various
  69   stages need to turn them into Common Lisp code, and run it."
  70  (clnl-nvm:with-stop-handler (eval (clnl-transpiler:transpile (clnl-parser:parse (clnl-lexer:lex cmds))))))
  71
  72 (defun run-reporter (reporter)
  73  "RUN-REPORTER REPORTER => RESULT
  74
  75 ARGUMENTS AND VALUES:
  76
  77   REPORTER: A string that should have only one reporter
  78   RESULT: The value reported by the NVM
  79
  80 DESCRIPTION:
  81
  82   RUN-REPORTER will take a NetLogo REPORTER, put it through the various
  83   stages need to turn them into Common Lisp code, run it, and return the RESULT."
  84  (eval (clnl-transpiler:transpile (clnl-parser:parse (clnl-lexer:lex reporter)))))
  85
  86 ; Because prims are used both at generation time and later at runtime, certain things in
  87 ; them must be escaped a little bit more, such as wrapping the whole thing in a list
  88 ; primitive.  This way, the output of these things looks like halfway decent lisp,
  89 ; and everything works nicely.  We don't want any <FUNC #> showing up or anything
  90 (defun munge-prim (prim)
  91  (let
  92   ((copied (copy-list prim)))
  93   (when (getf copied :args) (setf (getf copied :args) `(quote ,(getf copied :args))))
  94   `(list ,@copied)))
  95
  96 (defun netlogo-callback-body (prims)
  97  `(eval
  98    (clnl-transpiler:transpile
  99     (clnl-parser:parse
 100      (clnl-lexer:lex ,(intern "NETLOGO-CODE" *model-package*))
 101      (list ,@(mapcar #'munge-prim prims)))
 102     (list ,@(mapcar #'munge-prim prims)))))
 103
 104 (defun create-world-call (model globals code-ast)
 105  `(clnl-nvm:create-world
 106    :dims ',(clnl-model:world-dimensions model)
 107    :globals (list
 108              ,@(mapcar
 109                 (lambda (pair)
 110                  `(list ,(car pair) (lambda () ,(intern (string-upcase (car pair)) *model-package*))))
 111                 globals))
 112    :turtles-own-vars ',(clnl-code-parser:turtles-own-vars code-ast)
 113    :patches-own-vars ',(clnl-code-parser:patches-own-vars code-ast)
 114    :breeds ',(clnl-code-parser:breeds code-ast)))
 115
 116 (defun create-proc-body (proc prims)
 117  `(,(intern (string-upcase (car proc)) *model-package*) ()
 118    ,@(cdr ; remove the progn, cuz it looks nicer
 119       (clnl-transpiler:transpile (cadr proc)
 120        (mapcar
 121         (lambda (prim)
 122          (if (getf prim :macro) ; The reason we do this is because with macros, we want to evaluate them in
 123                                 ; this scope while preserving them for the generational purposes below
 124           (append (list :macro (eval (getf prim :macro))) prim)
 125           prim)) prims)))))
 126
 127 (defun model->single-form-lisp (model &key (seed 15) initialize-interface netlogo-callback)
 128  (multiple-value-bind
 129   (code-ast prims)
 130   (clnl-code-parser:parse (clnl-lexer:lex (clnl-model:code model)) (clnl-model:widget-globals model))
 131   (let
 132    ((globals
 133      (append
 134       (clnl-model:widget-globals model)
 135       (clnl-code-parser:globals code-ast))))
 136    `(prog ()
 137      ; First declare is in case we don't use it, it shows up in export correctly
 138      ,@(when (and (> (length globals) 0) netlogo-callback)
 139         `((declare (special ,@(mapcar (lambda (pair) (intern (string-upcase (car pair)) *model-package*)) globals)))))
 140      (let
 141       ,(mapcar (lambda (pair) (list (intern (string-upcase (car pair)) *model-package*) (cadr pair))) globals)
 142       ; We declare twice rather than once and doing a bunch of setfs
 143       ,@(when (and (> (length globals) 0) netlogo-callback)
 144          `((declare (special ,@(mapcar (lambda (pair) (intern (string-upcase (car pair)) *model-package*)) globals)))))
 145       (labels
 146        ,(mapcar
 147          (lambda (proc) (create-proc-body proc prims))
 148          (clnl-code-parser:procedures code-ast))
 149        (clnl-random:set-seed ,seed)
 150        ,(create-world-call model globals code-ast)
 151        ,@(when netlogo-callback
 152           `((funcall ,netlogo-callback
 153              (lambda (,(intern "NETLOGO-CODE" *model-package*))
 154               ,(netlogo-callback-body prims)))))
 155        ,@(when initialize-interface `((clnl-interface:initialize :dims ',(clnl-model:world-dimensions model))))))))))
 156
 157 (setf (documentation 'model->single-form-lisp 'function)
 158  "MODEL->SINGLE-FORM-LISP MODEL &key SEED INITIALIZE-INTERFACE NETLOGO-CALLBACK => FORM
 159
 160 ARGUMENTS AND VALUES:
 161
 162   MODEL: A valid model
 163   SEED: An integer, defaults to 15
 164   INITIALIZE-INTERFACE: A boolean
 165   NETLOGO-CALLBACK: A function of one argument, or a symbol
 166   FORM: A common lisp form
 167
 168 DESCRIPTION:
 169
 170   MODEL->SINGLE-FORM-LISP takes a model and returns a lisp program as a single form,
 171   that when executed runs the model.  The SEED passed in is used to start the
 172   clnl-random RNG.
 173
 174   INITIALIZE-INTERFACE, when non nil, leads to initialization code for the
 175   opengl interface being included.
 176
 177   NETLOGO-CALLBACK is a function that when called with a single argument,
 178   a function that when called with netlogo code, will compile and run that
 179   code in the environment of the model.
 180
 181   Of note, all globals defined either in the model code or via the widgets
 182   are declared special in order to remain in the lexical environment for EVAL.")
 183
 184 (defun model->multi-form-lisp (model boot-fn &key (seed 15) initialize-interface netlogo-callback-fn)
 185  (multiple-value-bind
 186   (code-ast prims)
 187   (clnl-code-parser:parse (clnl-lexer:lex (clnl-model:code model)) (clnl-model:widget-globals model))
 188   (let
 189    ((globals
 190      (append
 191       (clnl-model:widget-globals model)
 192       (clnl-code-parser:globals code-ast))))
 193    `((in-package ,(intern (package-name *model-package*) :keyword))
 194      ,@(mapcar
 195         (lambda (pair)
 196          `(defvar ,(intern (string-upcase (car pair)) *model-package*) ,(cadr pair)))
 197         globals)
 198      ,@(mapcar
 199         (lambda (proc) `(defun ,@(create-proc-body proc prims)))
 200         (clnl-code-parser:procedures code-ast))
 201      (defun ,boot-fn ()
 202       (clnl-random:set-seed ,seed)
 203       ,(create-world-call model globals code-ast)
 204       ,@(when initialize-interface `((clnl-interface:initialize :dims ',(clnl-model:world-dimensions model)))))
 205      ,@(when netlogo-callback-fn
 206         `((defun ,netlogo-callback-fn (,(intern "NETLOGO-CODE" *model-package*))
 207            ,(netlogo-callback-body prims))))))))
 208
 209 (setf (documentation 'model->multi-form-lisp 'function)
 210  "MODEL->MULTI-FORM-LISP MODEL BOOT-FN &key SEED INITIALIZE-INTERFACE NETLOGO-CALLBACK-FN => FORMS
 211
 212 ARGUMENTS AND VALUES:
 213
 214   MODEL: A valid model
 215   BOOT-FN: A function name
 216   SEED: An integer, defaults to 15
 217   INITIALIZE-INTERFACE: A boolean
 218   NETLOGO-CALLBACK-FN: a symbol
 219   FORMS: A list of common lisp form
 220
 221 DESCRIPTION:
 222
 223   MODEL->MULTI-FORM-LISP takes a model and returns a multi form lisp program,
 224   that when executed, sets up the model.  Procedures map to defuns, globals
 225   to defvars, etc.  This can be output to load up quickly later.  A function
 226   named by BOOT-FN will be set for booting the program.
 227
 228   The SEED passed in is used to start the clnl-random RNG.
 229
 230   INITIALIZE-INTERFACE, when non nil, leads to initialization code for the
 231   opengl interface being included.
 232
 233   NETLOGO-CALLBACK-FN is a symbol that will be defined as a function
 234   to be called to execute code in the running netlogo instance.")