code.consxy.com Git - clnl/blob - src/main/nvm/nvm.lisp

   1 (in-package #:clnl-nvm)
   2
   3 ; Implementations of all the things the nvm can do.
   4
   5 (defun show (value)
   6  "SHOW VALUE => RESULT
   7
   8 ARGUMENTS AND VALUES:
   9
  10   VALUE: a NetLogo value
  11   RESULT: undefined
  12
  13 DESCRIPTION:
  14
  15   A command that prints the given NetLogo value to the command center.
  16
  17   See http://ccl.northwestern.edu/netlogo/docs/dictionary.html#show"
  18  (format t "Showing: ~A~%" (dump-object value)))
  19
  20 (defun lookup-color (color)
  21  "LOOKUP-COLOR COLOR => COLOR-NUMBER
  22
  23 ARGUMENTS AND VALUES:
  24
  25   COLOR: a symbol representing a color
  26   COLOR-NUMBER: the NetLogo color integer
  27
  28 DESCRIPTION:
  29
  30   Returns the number used to represent colors in NetLogo.
  31
  32   See http://ccl.northwestern.edu/netlogo/docs/dictionary.html#Constants"
  33  (case color
  34   (:black 0d0)
  35   (:gray 5d0)
  36   (:white 9.9d0)
  37   (:red 15d0)
  38   (:orange 25d0)
  39   (:brown 35d0)
  40   (:yellow 45d0)
  41   (:green 55d0)
  42   (:lime 65d0)
  43   (:turquoise 75d0)
  44   (:cyan 85d0)
  45   (:sky 95d0)
  46   (:blue 105d0)
  47   (:violet 115d0)
  48   (:magenta 125d0)
  49   (:pink 135d0)))
  50
  51 (defun create-turtle ()
  52  (setf
  53   *turtles*
  54   (nconc
  55    *turtles*
  56    (list
  57     (make-turtle
  58      :who (coerce *current-id* 'double-float)
  59      :color (coerce (+ 5 (* 10 (clnl-random:next-int 14))) 'double-float)
  60      :heading (coerce (clnl-random:next-int 360) 'double-float)
  61      :xcor 0d0
  62      :ycor 0d0))))
  63  (incf *current-id*))
  64
  65 (defun die ()
  66  "DIE => RESULT
  67
  68 ARGUMENTS AND VALUES:
  69
  70   RESULT: undefined, commands don't return
  71
  72 DESCRIPTION:
  73
  74   The turtle or link dies
  75
  76   A dead agent ceases to exist. The effects of this include:
  77   - The agent will not execute any further code.
  78   - The agent will disappear from any agentsets it was in, reducing the size of those agentsets by one.
  79   - Any variable that was storing the agent will now instead have nobody in it.
  80   - If the dead agent was a turtle, every link connected to it also dies.
  81   - If the observer was watching or following the agent, the observer's perspective resets.
  82
  83   See http://ccl.northwestern.edu/netlogo/docs/dictionary.html#die"
  84  (when (not (turtle-p *self*)) (error "Gotta call die in turtle scope, dude (~A)" *self*))
  85  (setf (turtle-who *self*) -1)
  86  (setf *turtles* (remove *self* *turtles*)))
  87
  88 (defun patches ()
  89  "PATCHES => ALL-PATCHES
  90
  91 ARGUMENTS AND VALUES:
  92
  93   ALL-PATCHES: a NetLogo agentset, all patches
  94
  95 DESCRIPTION:
  96
  97   Reports the agentset consisting of all the patches.
  98
  99   This agentset is special in that it represents the living patches
 100   each time it's used, so changes depending on the state of the engine.
 101
 102   See http://ccl.northwestern.edu/netlogo/docs/dictionary.html#patches"
 103  *patches*)
 104
 105 (defun turtles ()
 106  "TURTLES => ALL-TURTLES
 107
 108 ARGUMENTS AND VALUES:
 109
 110   ALL-TURTLES: a NetLogo agentset, all turtles
 111
 112 DESCRIPTION:
 113
 114   Reports the agentset consisting of all the turtles.
 115
 116   This agentset is special in that it represents the living turtles
 117   each time it's used, so changes depending on the state of the engine.
 118
 119   See http://ccl.northwestern.edu/netlogo/docs/dictionary.html#turtles"
 120  *turtles*)
 121
 122 (defun ask (agent-set fn)
 123  "ASK AGENT-SET FN => RESULT
 124
 125 ARGUMENTS AND VALUES:
 126
 127   AGENT-SET: a NetLogo agentset
 128   FN: a function, run on each agent
 129   RESULT: undefined, commands don't return
 130
 131 DESCRIPTION:
 132
 133   ASK is equivalent to ask in NetLogo.
 134
 135   The specified AGENT-SET runs the given FN.  The order in which the agents
 136   are run is random each time, and only agents that are in the set at the
 137   beginning of the call.
 138
 139   See http://ccl.northwestern.edu/netlogo/docs/dictionary.html#ask"
 140  (let
 141   ((iter (shufflerator (agent-set-list agent-set))))
 142   (loop
 143    :for agent := (funcall iter)
 144    :while agent
 145    :do (let ((*myself* *self*) (*self* agent)) (funcall fn)))))
 146
 147 (defun of (fn agent-set)
 148  "OF FN AGENT-SET => RESULT
 149
 150 ARGUMENTS AND VALUES:
 151
 152   FN: a function, run on each agent
 153   AGENT-SET: a NetLogo agentset
 154   RESULT: a list
 155
 156 DESCRIPTION:
 157
 158   OF is equivalent to of in NetLogo.
 159
 160   The specified AGENT-SET runs the given FN.  The order in which the agents
 161   are run is random each time, and only agents that are in the set at the
 162   beginning of the call.  A list is returned of the returned valuse of
 163   FN.
 164
 165   See http://ccl.northwestern.edu/netlogo/docs/dictionary.html#of"
 166  (let
 167   ((iter (shufflerator (agent-set-list agent-set))))
 168   (loop
 169    :for agent := (funcall iter)
 170    :while agent
 171    :collect (let ((*myself* *self*) (*self* agent)) (funcall fn)))))
 172
 173 (defun shufflerator (agent-set-list)
 174  (let
 175   ((copy (copy-list agent-set-list))
 176    (i 0)
 177    (agent nil))
 178   (flet
 179    ((fetch ()
 180      (let
 181       ((idx (when (< i (1- (length copy))) (+ i (clnl-random:next-int (- (length copy) i))))))
 182       (when idx (setf agent (nth idx copy)))
 183       (when idx (setf (nth idx copy) (nth i copy)))
 184       (incf i))))
 185    (fetch) ; we pre-fetch because netlogo does, rng sync hype!
 186    (lambda ()
 187     (cond
 188      ((> i (length copy)) nil)
 189      ((= i (length copy)) (incf i) (car (last copy)))
 190      (t (let ((result agent)) (fetch) result)))))))
 191
 192 (defun random-float (n)
 193  "RANDOM-FLOAT N => RANDOM-NUMBER
 194
 195 ARGUMENTS AND VALUES:
 196
 197   N: a double, the upper bound of the random float
 198   RANDOM-NUMBER: a double, the random result
 199
 200 DESCRIPTION:
 201
 202   Returns a random number strictly closer to zero than N.
 203
 204   If number is positive, returns a random floating point number greater than
 205   or equal to 0 but strictly less than number.
 206
 207   If number is negative, returns a random floating point number less than or equal
 208   to 0, but strictly greater than number.
 209
 210   If number is zero, the result is always 0.
 211
 212   See http://ccl.northwestern.edu/netlogo/docs/dictionary.html#random-float"
 213  (clnl-random:next-double n))
 214
 215 (defun one-of (agent-set)
 216  "ONE-OF AGENT-SET => RESULT
 217
 218   RESULT: RANDOM-AGENT | :nobody
 219
 220 ARGUMENTS AND VALUES:
 221
 222   AGENT-SET: An agent set
 223   RANDOM-AGENT: an agent if AGENT-SET is non empty
 224
 225 DESCRIPTION:
 226
 227   From an agentset, returns a random agent. If the agentset is empty, returns nobody.
 228
 229   See http://ccl.northwestern.edu/netlogo/docs/dictionary.html#one-of"
 230  (let*
 231   ((agent-set-list (agent-set-list agent-set))
 232    (length (length agent-set-list)))
 233   (if (zerop length) :nobody (nth (clnl-random:next-int length) agent-set-list))))
 234
 235 (defun jump (n)
 236  (when (not (turtle-p *self*)) (error "Gotta call fd in turtle scope, dude (~A)" *self*))
 237  (setf
 238   (turtle-xcor *self*)
 239   (wrap-x *topology*
 240    (+ (turtle-xcor *self*) (* n (using-cached-sin (turtle-heading *self*))))))
 241  (setf
 242   (turtle-ycor *self*)
 243   (wrap-y *topology*
 244    (+ (turtle-ycor *self*) (* n (using-cached-cos (turtle-heading *self*)))))))
 245
 246 (defun forward (n)
 247  "FORWARD N => RESULT
 248
 249 ARGUMENTS AND VALUES:
 250
 251   N: a double, the amount the turtle moves forward
 252   RESULT: undefined
 253
 254 DESCRIPTION:
 255
 256   Moves the current turtle forward N steps, one step at a time.
 257
 258   This moves forward one at a time in order to make the view updates look
 259   good in the case of a purposefully slow running instance.  If the number
 260   is negative, the turtle moves backward.
 261
 262   If the current agent is not a turtle, it raises an error.
 263
 264   See http://ccl.northwestern.edu/netlogo/docs/dictionary.html#forward"
 265  (when (not (turtle-p *self*)) (error "Gotta call fd in turtle scope, dude (~A)" *self*))
 266  (labels
 267   ((internal (i)
 268     (cond
 269      ((< (abs i) 3.2e-15) nil)
 270      ((< (abs i) 1d0) (jump i))
 271      (t (jump (if (> i 0d0) 1d0 -1d0)) (internal (- i (if (> i 0d0) 1d0 -1d0)))))))
 272   (internal n)))
 273
 274 (defun turn-right (n)
 275  "TURN-RIGHT N => RESULT
 276
 277 ARGUMENTS AND VALUES:
 278
 279   N: a double, the amount the turtle turns
 280   RESULT: undefined
 281
 282 DESCRIPTION:
 283
 284   The turtle turns right by number degrees. (If number is negative, it turns left.)
 285
 286   See http://ccl.northwestern.edu/netlogo/docs/dictionary.html#right"
 287  (when (not (turtle-p *self*)) (error "Gotta call fd in turtle scope, dude (~A)" *self*))
 288  (let
 289   ((new-heading (+ (turtle-heading *self*) n)))
 290   (setf (turtle-heading *self*)
 291    (cond
 292     ((< new-heading 0) (+ (mod new-heading -360) 360))
 293     ((>= new-heading 360) (mod new-heading 360))
 294     (t new-heading)))))
 295
 296 (defun turn-left (n)
 297  "TURN-LEFT N => RESULT
 298
 299 ARGUMENTS AND VALUES:
 300
 301   N: a double, the amount the turtle turns
 302   RESULT: undefined
 303
 304 DESCRIPTION:
 305
 306   The turtle turns left by number degrees. (If number is negative, it turns right.)
 307
 308   See http://ccl.northwestern.edu/netlogo/docs/dictionary.html#right"
 309  (turn-right (- n)))
 310
 311 (defun create-turtles (n)
 312  "CREATE-TURTLES N => RESULT
 313
 314 ARGUMENTS AND VALUES:
 315
 316   N: an integer, the numbers of turtles to create
 317   RESULT: undefined
 318
 319 DESCRIPTION:
 320
 321   Creates number new turtles at the origin.
 322
 323   New turtles have random integer headings and the color is randomly selected
 324   from the 14 primary colors.  If commands are supplied, the new turtles
 325   immediately run them (unimplemented).
 326
 327   See http://ccl.northwestern.edu/netlogo/docs/dictionary.html#create-turtles"
 328  (loop :for i :from 1 :to n :do (create-turtle)))
 329
 330 (defun reset-ticks ()
 331  "RESET-TICKS => RESULT
 332
 333 ARGUMENTS AND VALUES:
 334
 335   RESULT: undefined
 336
 337 DESCRIPTION:
 338
 339   Resets the tick counter to zero, sets up all plots, then updates all plots.
 340
 341   See http://ccl.northwestern.edu/netlogo/docs/dictionary.html#reset-ticks"
 342  (setf *ticks* 0d0))
 343
 344 (defun tick ()
 345  "RESET-TICKS => RESULT
 346
 347 ARGUMENTS AND VALUES:
 348
 349   RESULT: undefined
 350
 351 DESCRIPTION:
 352
 353   Advances the tick counter by one and updates all plots.
 354
 355   If the tick counter has not been started yet with reset-ticks, an error results.
 356
 357   See http://ccl.northwestern.edu/netlogo/docs/dictionary.html#tick"
 358
 359  (when (not *ticks*) (error "reset-ticks must be called"))
 360  (incf *ticks*))
 361
 362 (defun ticks ()
 363  "TICKS => CURRENT-TICKS
 364
 365 ARGUMENTS AND VALUES:
 366
 367   CURRENT-TICKS: A positiv double, representing the current number of ticks
 368
 369 DESCRIPTION:
 370
 371   Reports the current value of the tick counter. The result is always a number and never negative.
 372
 373   If the tick counter has not been started yet with reset-ticks, an error results.
 374
 375   See http://ccl.northwestern.edu/netlogo/docs/dictionary.html#ticks"
 376  (when (not *ticks*) (error "reset-ticks must be called"))
 377  *ticks*)
 378
 379 (defun create-world (&key dims)
 380  "CREATE-WORLD &key DIMS => RESULT
 381
 382   DIMS: (:xmin XMIN :xmax XMAX :ymin YMIN :ymax YMAX)
 383
 384 ARGUMENTS AND VALUES:
 385
 386   RESULT: undefined
 387   XMIN: An integer representing the minimum patch coord in X
 388   XMAX: An integer representing the maximum patch coord in X
 389   YMIN: An integer representing the minimum patch coord in Y
 390   YMAX: An integer representing the maximum patch coord in Y
 391
 392 DESCRIPTION:
 393
 394   Initializes the world in the NVM.
 395
 396   This should be called before using the engine in any real capacity.  If
 397   called when an engine is already running, it may do somethign weird."
 398  (setf *dimensions* dims)
 399  (setf
 400   *patches*
 401   (loop
 402    :for y :from (max-pycor) :downto (min-pycor)
 403    :append (loop
 404             :for x :from (min-pxcor) :to (max-pxcor)
 405             :collect (make-patch
 406                       :xcor (coerce x 'double-float)
 407                       :ycor (coerce y 'double-float)
 408                       :color 0d0))))
 409  (setf *turtles* nil)
 410  (setf *current-id* 0))
 411
 412 ; These match netlogo's dump
 413 (defgeneric dump-object (o))
 414
 415 (defmethod dump-object ((n double-float))
 416  (multiple-value-bind (int rem) (floor n)
 417   (if (eql 0d0 rem)
 418    (format nil "~A" int)
 419    (let
 420     ((output (format nil "~D" n)))
 421     ; Someday we'll have d<posint>, but this is not that day!
 422     (cl-ppcre:regex-replace "d-" (cl-ppcre:regex-replace "d0" output "") "E-")))))
 423
 424 (defmethod dump-object ((o string)) (format nil "~A" (cl-ppcre:regex-replace-all "\"" (format nil "~S" o) "\"\"")))
 425
 426 (defmethod dump-object ((o (eql t))) "true")
 427 (defmethod dump-object ((o (eql nil))) "false")
 428
 429 (defmethod dump-object ((o list)) (format nil "[~{~A~^ ~}]" (mapcar #'dump-object o)))
 430
 431 (defmethod dump-object ((o patch))
 432  (format nil "(patch ~A ~A)" (dump-object (patch-xcor o)) (dump-object (patch-ycor o))))
 433
 434 (defmethod dump-object ((o turtle)) (format nil "(turtle ~A)" (dump-object (turtle-who o))))
 435 (defmethod dump-object ((o (eql :nobody))) (format nil "nobody"))
 436
 437 (defun current-state ()
 438  "CURRENT-STATE => WORLD-STATE
 439
 440 ARGUMENTS AND VALUES:
 441
 442   WORLD-STATE: A list, the current state of the whole world
 443
 444 DESCRIPTION:
 445
 446   Dumps out the state of the world.
 447
 448   This is useful for visualizations and also storing in a common lisp
 449   data structure for easy usage in a common lisp instance.  It's preferable
 450   to use this when working with the nvm than the output done by export-world.
 451
 452   Currently this only dumps out turtle and patch information.
 453
 454   This is called CURRENT-STATE because export-world is an actual primitive
 455   used by NetLogo."
 456  (list
 457   (mapcar
 458    (lambda (turtle)
 459     (list
 460      :color (turtle-color turtle)
 461      :xcor (turtle-xcor turtle)
 462      :ycor (turtle-ycor turtle)
 463      :heading (turtle-heading turtle)
 464      :size (turtle-size turtle)))
 465    *turtles*)
 466   (mapcar
 467    (lambda (patch)
 468     (list
 469      :color (patch-color patch)
 470      :xcor (patch-xcor patch)
 471      :ycor (patch-ycor patch)))
 472    *patches*)))
 473
 474 (defun export-turtles ()
 475  (append
 476   (list
 477    "\"TURTLES\""
 478    (format nil "~A~A"
 479     "\"who\",\"color\",\"heading\",\"xcor\",\"ycor\",\"shape\",\"label\",\"label-color\","
 480     "\"breed\",\"hidden?\",\"size\",\"pen-size\",\"pen-mode\""))
 481   (mapcar
 482    (lambda (turtle)
 483     (format nil
 484      "\"~A\",\"~A\",\"~A\",\"~A\",\"~A\",\"\"\"default\"\"\",\"~A\",\"~A\",\"{all-turtles}\",\"false\",\"~A\",~A"
 485      (dump-object (turtle-who turtle))
 486      (dump-object (turtle-color turtle))
 487      (dump-object (turtle-heading turtle))
 488      (dump-object (turtle-xcor turtle))
 489      (dump-object (turtle-ycor turtle))
 490      (dump-object (turtle-label turtle))
 491      (dump-object (turtle-label-color turtle))
 492      (dump-object (turtle-size turtle))
 493      "\"1\",\"\"\"up\"\"\""))
 494    *turtles*)))
 495
 496 (defun export-patches ()
 497  (append
 498   (list
 499    "\"PATCHES\""
 500    "\"pxcor\",\"pycor\",\"pcolor\",\"plabel\",\"plabel-color\"")
 501   (mapcar
 502    (lambda (patch)
 503     (format nil
 504      "\"~A\",\"~A\",\"~A\",\"\"\"\"\"\",\"9.9\""
 505      (dump-object (patch-xcor patch))
 506      (dump-object (patch-ycor patch))
 507      (dump-object (patch-color patch))))
 508    *patches*)))
 509
 510 (defun export-world ()
 511  "EXPORT-WORLD => WORLD-CSV
 512
 513 ARGUMENTS AND VALUES:
 514
 515   WORLD-CSV: A string, the csv of the world
 516
 517 DESCRIPTION:
 518
 519   Dumps out a csv matching NetLogo's export world.
 520
 521   This is useful for serializing the current state of the engine in order
 522   to compare against NetLogo or to reimport later.  Contains everything needed
 523   to boot up a NetLogo instance in the exact same state."
 524  (format nil "~{~A~%~}"
 525   (list
 526    (format nil "~S" "RANDOM STATE")
 527    (format nil "~S" (clnl-random:export))
 528    ""
 529    (format nil "~S" "GLOBALS")
 530    (format nil "~A~A"
 531     "\"min-pxcor\",\"max-pxcor\",\"min-pycor\",\"max-pycor\",\"perspective\",\"subject\","
 532     "\"nextIndex\",\"directed-links\",\"ticks\",")
 533    (format nil "\"~A\",\"~A\",\"~A\",\"~A\",\"0\",\"nobody\",\"~A\",\"\"\"NEITHER\"\"\",\"-1\""
 534     (min-pxcor) (max-pxcor) (min-pycor) (max-pycor) *current-id*)
 535    ""
 536    (format nil "~{~A~^~%~}" (export-turtles))
 537    ""
 538    (format nil "~{~A~^~%~}" (export-patches))
 539    ""
 540    (format nil "~S" "LINKS")
 541    "\"end1\",\"end2\",\"color\",\"label\",\"label-color\",\"hidden?\",\"breed\",\"thickness\",\"shape\",\"tie-mode\""
 542    "")))