code.consxy.com Git - wolf/blob - src/main/syntax-checker.lisp

   1 (in-package #:syntax-checker)
   2
   3 ; Rules
   4 ; * Elements on new line in each form must be indented the same amount
   5 ; * No space/newline after open parens
   6 ; * No form longer than 50 lines
   7 ; * Top level multiline forms must be separated by exactly one space
   8 ; * No line longer than 120 characters
   9 ; * No use of unexported symbols in other packages
  10 ; * No tabs
  11 ; * Only one space between elements in a form on a single line
  12 ; * in-package must be first line in file unless file is package.lisp
  13 ; * No whitespace at end of line
  14 ; * No lines that are only whitespace
  15 ; * No empty lines at end of file
  16 ; * Never have two empty lines in a row
  17 ; * Only one in-package per file
  18 ; * No hanging close parens
  19 ;
  20 ; Exceptions
  21 ; * comments
  22 ; * multiline strings
  23 ; * exclude in-package check from package.lisp
  24
  25 ; Some thoughts
  26 ; - form starting reader macros will have to be hand added to this code
  27 ; - exceptions will eventually arise, and the rule file will have to be changed
  28 ; - the proper formatting of "loop" is weird
  29
  30 (define-condition check-failure nil ((msg :initarg :msg :reader check-failure-msg)
  31                                      (line-no :initarg :line-no :reader check-failure-line-no)
  32                                      (col-no :initarg :col-no :reader check-failure-col-no)))
  33
  34 (defvar *state* nil)
  35 (defvar *line-no* nil)
  36 (defvar *col-no* nil)
  37 (defvar *evaluators* nil)
  38 (defvar *form-stack* nil)
  39 (defvar *form-ended-on-same-line* nil)
  40
  41 (eval-when (:compile-toplevel :load-toplevel :execute)
  42  (defparameter *possible-states*
  43   '(:begin ; start of file
  44     :normal ; normal processing
  45     :beginning-of-line
  46     :beginning-of-line-with-separator ; empty space in there
  47     :beginning-of-symbols
  48     :beginning-of-symbols-with-separator
  49     :comment-with-separator ; weird edge case for pre-function comments
  50     :beginning-of-line-with-comment-and-separator ; weird edge case part 2
  51     :first-symbol ; first symbol of form/line
  52     :all ; matches everything
  53     :in-string)))
  54
  55 (defun set-state (state)
  56  (when (not (find state *possible-states*))
  57   (error "Can't set state to ~A" state))
  58  (setf *state* state)
  59  nil)
  60
  61 (defmacro defevaluator (state match func)
  62  (when (not (find state *possible-states*)) (error "~A is an invalid state" state))
  63  (let
  64   ((scanner (gensym)))
  65   `(let
  66     ((,scanner (when (stringp ,match) (cl-ppcre:create-scanner ,match))))
  67     (pushnew
  68      (list
  69       (lambda (state text)
  70        (and
  71         (or (eql :all ,state) (eql ,state state))
  72         (or
  73          (and (symbolp text) (eql text ,match))
  74          (and
  75           ,scanner
  76           (stringp text)
  77           (multiple-value-bind (start end) (cl-ppcre:scan ,scanner text)
  78            (and start end (= 0 start)))))))
  79       (lambda (text) (second (multiple-value-list (cl-ppcre:scan ,scanner text))))
  80       ,func)
  81      *evaluators*))))
  82
  83 (defun evaluate (text)
  84  (if (string= "" text)
  85   (let*
  86    ((evaluator (find-if (lambda (f) (funcall f *state* :eof)) *evaluators* :from-end t :key #'car))
  87     (problem (when evaluator (funcall (third evaluator)))))
  88    (when problem (error (make-condition 'check-failure :msg problem :line-no *line-no* :col-no *col-no*))))
  89   (let
  90    ((evaluator (find-if (lambda (f) (funcall f *state* text)) *evaluators* :from-end t :key #'car)))
  91    (when (not evaluator)
  92     (error
  93      (make-condition 'check-failure
  94       :msg (format nil "Can't check in state ~S: ~S..."
  95             *state* (subseq text 0 (min (length text) 10))) :line-no *line-no* :col-no *col-no*)))
  96    (let
  97     ((problem (funcall (third evaluator))))
  98     (when problem
  99      (error (make-condition 'check-failure :msg problem :line-no *line-no* :col-no *col-no*)))
 100     (let
 101      ((length-of-match (funcall (cadr evaluator) text)))
 102      (incf *col-no* length-of-match)
 103      (when (< 120 *col-no*)
 104       (error (make-condition 'check-failure :msg "Line longer than 120 characters" :line-no *line-no* :col-no 0)))
 105      (evaluate (subseq text length-of-match)))))))
 106
 107 (defun slurp-file (filename &key (element-type 'character) (sequence-type 'string))
 108  (with-open-file (str filename :element-type element-type)
 109   (let ((seq (make-sequence sequence-type (file-length str)))) (read-sequence seq str) seq)))
 110
 111 (defun check-file (file)
 112  (if (string= "package" (pathname-name file))
 113   (set-state :normal)
 114   (set-state :begin))
 115  (setf *line-no* 0)
 116  (setf *col-no* 0)
 117  (setf *form-stack* nil)
 118  (setf *form-ended-on-same-line* nil)
 119  (handler-case
 120   (progn
 121    (evaluate (slurp-file file))
 122    (list :success file))
 123   (check-failure (cf)
 124    (list :failure file (check-failure-msg cf) (check-failure-line-no cf) (check-failure-col-no cf)))))
 125
 126 (defun check-directory (dir)
 127  (mapcar #'check-file (directory (format nil "~A/**/*.lisp" dir))))
 128
 129 (defun any-failures (checks)
 130  (find :failure checks :key #'car))
 131
 132 (defun print-failure (failure)
 133  (format nil
 134   "Style error in ~A at ~A:~A: ~A~%- ~A~%~VT^"
 135   (second failure)
 136   (1+ (fourth failure))
 137   (1+ (fifth failure))
 138   (third failure)
 139   (with-open-file (str (second failure)) (loop :repeat (fourth failure) :do (read-line str)) (read-line str))
 140   (+ (fifth failure) 2)))
 141
 142 (defun pretty-print-check-directory (dir)
 143  (let
 144   ((checks (check-directory dir)))
 145   (format t "In ~A: Checked ~A files with ~A failures~%~%"
 146    dir (length checks) (length (remove :success checks :key #'car)))
 147   (format t "~{~A~%~}" (mapcar #'print-failure (remove :success checks :key #'car)))
 148   (not (any-failures checks))))
 149
 150 ; These are in reverse order
 151 (defevaluator :beginning-of-symbols " *;[^\\n]*"
 152  (lambda () (set-state :normal)))
 153
 154 (defevaluator :beginning-of-symbols-with-separator " *;[^\\n]*"
 155  (lambda () (set-state :comment-with-separator)))
 156
 157 (defevaluator :normal " *;[^\\n]*"
 158  (lambda () (set-state :normal)))
 159
 160 (defevaluator :normal "\\("
 161  (lambda ()
 162   (push (list *line-no* *col-no*) *form-stack*)
 163   (set-state :first-symbol)))
 164
 165 (defevaluator :first-symbol "\\("
 166  (lambda ()
 167   (cond
 168    ((and (not *form-stack*) (not (zerop *col-no*))) "Top level forms must begin on first column")
 169    ((and *form-stack* (/= (1+ (cadr (car *form-stack*))) *col-no*))
 170     "All form elements must be indented equally")
 171    (t
 172     (push (list *line-no* *col-no*) *form-stack*)
 173     (set-state :first-symbol)))))
 174
 175 (defevaluator :all "\\t" (constantly "Must not use tabs"))
 176
 177 (defevaluator :begin "\\(in-package[^\\)]*\\)" (lambda () (set-state :normal)))
 178
 179 (defevaluator :beginning-of-line-with-separator :eof
 180  (lambda ()
 181   (incf *line-no* -1)
 182   "Must not end with empty line"))
 183
 184 (defevaluator :beginning-of-line-with-separator "\\n" (constantly "Must not have two empty lines in a row"))
 185
 186 (defevaluator :begin ".*" (constantly "Must begin with in-package form"))
 187
 188 (defevaluator :all "\\( *in-package " (constantly "Only one in-package per file"))
 189
 190 (defevaluator :normal "\\n"
 191  (lambda ()
 192   (incf *line-no*)
 193   (setf *col-no* -1)
 194   (set-state :beginning-of-line)))
 195
 196 (defevaluator :comment-with-separator "\\n"
 197  (lambda ()
 198   (incf *line-no*)
 199   (setf *col-no* -1)
 200   (set-state :beginning-of-line-with-comment-and-separator)
 201   nil))
 202
 203 (defevaluator :normal " +\\n" (constantly "No whitespace at end of line"))
 204
 205 (defevaluator :beginning-of-line " *" (lambda () (set-state :beginning-of-symbols)))
 206
 207 (defevaluator :beginning-of-line-with-separator " *" (lambda () (set-state :beginning-of-symbols-with-separator)))
 208
 209 (defevaluator :beginning-of-line-with-comment-and-separator "\\n"
 210  (lambda ()
 211   (progn
 212    (incf *line-no*)
 213    (setf *col-no* -1)
 214    (set-state :beginning-of-line-with-separator))))
 215
 216 (defevaluator :beginning-of-line-with-comment-and-separator " *"
 217  (lambda () (set-state :beginning-of-symbols-with-separator)))
 218
 219 (defevaluator :beginning-of-symbols "\\n"
 220  (lambda ()
 221   (if
 222    (< 0 *col-no*)
 223    "No whitespace only lines"
 224    (progn
 225     (incf *line-no*)
 226     (setf *col-no* -1)
 227     (set-state :beginning-of-line-with-separator)))))
 228
 229 (defevaluator :beginning-of-symbols "\\)" (constantly "No hanging close parens"))
 230
 231 (defevaluator :beginning-of-symbols-with-separator "\\)" (constantly "No hanging close parens"))
 232
 233 (defevaluator :beginning-of-symbols ""
 234  (lambda ()
 235   (if
 236    (and (not *form-stack*) (not *form-ended-on-same-line*))
 237    "Multiline top level forms must be separated by a space"
 238    (set-state :first-symbol))))
 239
 240 (defevaluator :beginning-of-symbols-with-separator ""
 241  (lambda ()
 242   (set-state :first-symbol)))
 243
 244 (defevaluator :normal "\\)"
 245  (lambda ()
 246   (let
 247    ((form (pop *form-stack*)))
 248    (cond
 249     ((not form) "Unmatched ending paren")
 250     ((< 50 (- *line-no* (car form))) "Forms can't be over 50 lines long")
 251     (t (setf *form-ended-on-same-line* (= *line-no* (car form))) nil)))))
 252
 253 (defevaluator :normal "::" (constantly "No internal symbols from other packages"))
 254
 255 (defevaluator :in-string "\\\\\"" (constantly nil))
 256
 257 (defevaluator :normal "\"" (lambda () (set-state :in-string)))
 258
 259 (defevaluator :in-string "\"" (lambda () (set-state :normal)))
 260
 261 (defevaluator :in-string "\\n"
 262  (lambda ()
 263   (incf *line-no*)
 264   (setf *col-no* -1)
 265   nil))
 266
 267 (defevaluator :in-string "." (constantly nil))
 268
 269 (defevaluator :first-symbol "\\n" (constantly "No new line after opening form"))
 270
 271 (defevaluator :first-symbol " " (constantly "No space after opening parens"))
 272
 273 (defevaluator :first-symbol ""
 274  (lambda ()
 275   (cond
 276    ((and *form-stack* (/= (1+ (cadr (car *form-stack*))) *col-no*))
 277     "All form elements must be indented equally")
 278    (t (set-state :normal)))))
 279
 280 (defevaluator :normal "  " (constantly "Only one space between items of a form"))
 281
 282 (defevaluator :normal "." (constantly nil))