(in-package #:candle)

(defun server (port &optional (background t))
 (when (not *candle-dir*) (error "Need a candle dir"))
 (let*
  ((data-dir (format nil "~Adata" *candle-dir*))
   (log-dir (format nil "~Alogs/" *candle-dir*)))
  (ensure-directories-exist *candle-dir*)
  (ensure-directories-exist data-dir)
  (ensure-directories-exist log-dir)
  (setf log-utils:*log-dir* log-dir)
  (log:add-appender #'log-utils:file-appender)
  (log:info "Starting server on port ~A" port)
  (lame-db:load-known-dbs data-dir)
  (log:info "Starting processor in ~(~A~) mode" *job-system*)
  (start-save-thread data-dir)
  (start-processor-thread)
  (communication:start-listener port background)))

(defun start-save-thread (data-dir)
 (log:info "Starting Save Thread")
 (let*
  ((mutex (sb-thread:make-mutex))
   (waitq (sb-thread:make-waitqueue))
   (active t)
   (save-thread
    (sb-thread:make-thread
     (lambda ()
      (loop
       :while active
       :do
       (sb-thread:with-mutex (mutex)
        (sb-thread:condition-wait waitq mutex)))
      (lame-db:save-known-dbs data-dir))
     :name "Save Thread")))
  (sb-thread:make-thread
   (lambda ()
    (loop
     (sleep (* 1 60))
     (sb-thread:with-mutex (mutex)
      (sb-thread:condition-broadcast waitq))))
   :name "Save Thread Trigger")
  (push
   (lambda ()
    (log:info "Shutting down save thread")
    (sb-thread:with-mutex (mutex)
     (setf active nil)
     (sb-thread:condition-broadcast waitq))
    (sb-thread:join-thread save-thread))
   sb-ext:*exit-hooks*)))

(defun find-project-by-name-or-die (name)
 (when name
  (or
   (find name *all-project* :test #'string= :key #'project-name)
   (raise-candle-error :project-does-not-exist))))

(defun add-project (name src)
 (when
  (not (cl-ppcre:scan "^[0-9A-Za-z-]*$" name))
  (raise-candle-error :invalid-project-name))
 (when
  (not (git nil "ls-remote" src))
  (raise-candle-error :invalid-project-uri))
 (when
  (find name *all-project* :test #'string= :key #'project-name)
  (raise-candle-error :project-name-taken))
 (let
  ((project (make-project :name name :src src)))
  (ensure-directories-exist (project-dir project))
  (git project "clone" src ".")
  (refresh-project name))
 t)

(defun refresh-project (name)
 (let*
  ((project (find-project-by-name-or-die name))
   (branches (find-branch-by-project project)))
  (git project "fetch" "origin" "--prune")
  (multiple-value-bind (success code out err) (git project "branch" "-r" "--format" "%(refname) %(objectname)" "--list" "origin/*")
   (declare (ignore code err))
   (when (not success) (raise-candle-error :project-failed-to-get-branches))
   (mapcar (lambda (branch) (set-branch-in-git branch nil)) branches)
   (mapcar
    (lambda (line)
     (cl-ppcre:register-groups-bind (branch-name sha) ("refs/remotes/origin/(.*) (.*)" line)
      (let*
       ((job
         (or
          (find sha (find-job-by-project project) :test #'string= :key #'job-sha)
          (make-job :status :queued :sha sha :project project :create-date (get-universal-time))))
        (branch
         (or
          (find branch-name branches :test #'string= :key #'branch-name)
          (make-branch :name branch-name :project project))))
       (set-branch-in-git branch t)
       (set-branch-job branch job))))
    (cl-ppcre:split "\\n" out))))
 (awaken-processor-thread))

(defun delete-project (name)
 (let
  ((project (find-project-by-name-or-die name)))
  (sb-ext:delete-directory (project-dir project) :recursive t)
  (mapcar #'nremove-job (find-job-by-project project))
  (mapcar #'nremove-branch (find-branch-by-project project))
  (nremove-project project)))

(defun job->job-information (job)
 (list (project-name (job-project job)) (job-sha job) (job-status job) (job-create-date job)))

(defun project-branch-information (name)
 (let
  ((project (find-project-by-name-or-die name)))
  (mapcar
   (lambda (branch)
    (list
     (branch-name branch)
     (job->job-information (branch-job branch))))
   (remove-if-not #'branch-in-git (find-branch-by-project project)))))

(defun project-job-information (name)
 (let
  ((project (find-project-by-name-or-die name)))
  (mapcar #'job->job-information
   (if project
    (find-job-by-project project)
    *all-job*))))

(defun find-job-by-project-and-sha (project-name sha)
 (let*
  ((project (find project-name *all-project* :test #'string= :key #'project-name))
   (job
    (when project
     (find-if
      (lambda (job-sha)
       (and (<= (length sha) (length job-sha)) (string= sha (subseq job-sha 0 (length sha)))))
     (find-job-by-project project)
     :key #'job-sha))))
  (when (not job) (raise-candle-error :job-does-not-exist))
  job))

(defun get-job-log (project-name sha)
 (job-log (find-job-by-project-and-sha project-name sha)))

(defun retry-job (project-name sha)
 (set-job-status (find-job-by-project-and-sha project-name sha) :queued)
 (awaken-processor-thread))

(defun list-projects ()
 (mapcar
  (lambda (project)
   (list
    (project-name project)
    (project-src project)
    (failures (project-name project))))
  *all-project*))

(defun failures (project-name)
 (let
  ((project (find-project-by-name-or-die project-name)))
  (length
   (remove-if-not
    (lambda (branch) (eql :failed (job-status (branch-job branch))))
    (if project (find-branch-by-project project) *all-branch*)))))