(in-package #:candle)

(defun server (port &optional (background t))
 (when (not *candle-dir*) (error "Need a candle dir"))
 (let
  ((data-dir (format nil "~Adata" *candle-dir*)))
  (ensure-directories-exist *candle-dir*)
  (ensure-directories-exist data-dir)
  (lame-db:load-known-dbs data-dir)
  (sb-thread:make-thread
   (lambda ()
    (do () (nil)
     (progn
      (sleep (* 5 60))
      (lame-db:save-known-dbs data-dir))))
   :name "Save Thread")
  (format t "Starting processor in ~(~A~) mode~%" *job-system*)
  (start-processor-thread)
  (communication:start-listener port background)))

(defun add-project (name src)
 (when
  (not (cl-ppcre:scan "^[0-9A-Za-z-]*$" name))
  (error "Name contains invalid characters"))
 (when
  (not (git nil "ls-remote" src))
  (error "Project uri is not a valid git repository"))
 (when
  (find name *all-project* :test #'string= :key #'project-name)
  (error "Project name already taken"))
 (let
  ((project (make-project :name name :src src)))
  (ensure-directories-exist (project-dir project))
  (git project "clone" src ".")
  (refresh-project name))
 t)

(defun refresh-project (name)
 (let*
  ((project (find name *all-project* :test #'string= :key #'project-name))
   (branches (find-branch-by-project project)))
  (git project "fetch" "origin" "--prune")
  (multiple-value-bind (success code out err) (git project "branch" "-r" "--format" "%(refname) %(objectname)" "--list" "origin/*")
   (declare (ignore code err))
   (when (not success) (error "Failed to get branches"))
   (mapcar (lambda (branch) (set-branch-in-git branch nil)) branches)
   (mapcar
    (lambda (line)
     (cl-ppcre:register-groups-bind (branch-name sha) ("refs/remotes/origin/(.*) (.*)" line)
      (let*
       ((job
         (or
          (find sha (find-job-by-project project) :test #'string= :key #'job-sha)
          (make-job :status :queued :sha sha :project project :create-date (get-universal-time))))
        (branch
         (or
          (find branch-name branches :test #'string= :key #'branch-name)
          (make-branch :name branch-name :project project))))
       (set-branch-in-git branch t)
       (set-branch-job branch job))))
    (cl-ppcre:split "\\n" out))))
 (awaken-processor-thread))

(defun delete-project (name)
 (let
  ((project (find name *all-project* :test #'string= :key #'project-name)))
  (when (not project) (error "Project does not exist"))
  (sb-ext:delete-directory (project-dir project) :recursive t)
  (mapcar #'nremove-job (find-job-by-project project))
  (mapcar #'nremove-branch (find-branch-by-project project))
  (nremove-project project)))

(defun job->job-information (job)
 (list (job-sha job) (job-status job) (job-create-date job)))

(defun project-branch-information (name)
 (let
  ((project (find name *all-project* :test #'string= :key #'project-name)))
  (when (not project) (error "Project does not exist"))
  (mapcar
   (lambda (branch)
    (list
     (branch-name branch)
     (job->job-information (branch-job branch))))
   (remove-if-not #'branch-in-git (find-branch-by-project project)))))

(defun project-job-information (name)
 (let
  ((project (find name *all-project* :test #'string= :key #'project-name)))
  (when (not project) (error "Project does not exist"))
  (mapcar #'job->job-information (find-job-by-project project))))