code.consxy.com Git - candle/blob - src/main/cli.lisp

   1 (in-package #:candle-cli)
   2
   3 (defun main-options ()
   4  '((:name :help :short "h" :long "help" :description "Print this usage.")
   5    (:name :port :short "p" :long "port" :takes-argument t :variable-name "PORT"
   6     :description "Port on which to listen for commands.  Defaults to 25004")
   7    (:positional "<command>" :required t :description "Command to send to candle server")))
   8
   9 (defun project-options ()
  10  '((:name :help :short "h" :long "help" :description "Print this usage.")
  11    (:name :add :long "add" :takes-argument t :description
  12     "Add a project.  NAME is the name of the project, which must not include colons, while SRC is the location of the repository for cloning.  This location must be accessible by the machine running candle."
  13     :variable-name "NAME:SRC")
  14    (:name :show :long "show" :takes-argument t :description
  15     "Show branch information for a project named by NAME."
  16     :variable-name "NAME")
  17    (:name :refresh :long "refresh" :takes-argument t :description
  18     "Refresh project named by NAME."
  19     :variable-name "NAME")
  20    (:name :delete :long "delete" :takes-argument t :description
  21     "Delete a project named by NAME."
  22     :variable-name "NAME")))
  23
  24 (defun job-options ()
  25  '((:name :help :short "h" :long "help" :description "Print this usage.")
  26    (:name :project-name :long "project" :takes-argument t :description "The project name for the jobs under consideration.")))
  27
  28 (defun run-options ()
  29  '((:name :help :short "h" :long "help" :description "Print this usage.")))
  30
  31 (defun main-usage ()
  32  (format t "~A"
  33   (opera:usage
  34    "candle"
  35    (main-options)
  36    "Interacts with candle server.  The available commands are:
  37   project   List, show or add projects
  38   job       List or show jobs
  39   run       Local command.  Run candle in the current working directory")))
  40
  41 (defgeneric execute-command (command args))
  42
  43 (defmethod execute-command (command args)
  44  (format *error-output* "Unknown command '~(~A~)'.  See 'candle --help'.~%" command))
  45
  46 (defun add-project (project-definition)
  47  (let
  48   ((pos (position #\: project-definition)))
  49   (cond
  50    ((not pos) (format *error-output* "Project definition ~A is not valid.  See 'candle project --help'.~%" project-definition))
  51    (t
  52     (let*
  53      ((name (subseq project-definition 0 pos))
  54       (src (subseq project-definition (1+ pos))))
  55      (communication:query `(candle:add-project ,name ,src))
  56      (format t "Added project ~A at src definition ~A~%" name src))))))
  57
  58 (defun delete-project (name)
  59  (communication:query `(candle:delete-project ,name))
  60  (format t "Removed project ~A~%" name))
  61
  62 (defun show-project (name)
  63  (mapcar
  64   (lambda (branch-info)
  65    (format t "~A: ~A ~A at ~A~%"
  66     (first branch-info)
  67     (fourth branch-info)
  68     (case (second branch-info)
  69      (:succeeded (format nil "~c[1;32mPassed~c[0m" #\Esc #\Esc))
  70      (:failed (format nil "~c[1;31mFailed~c[0m" #\Esc #\Esc))
  71      (:queued "In queue")
  72      (:no-candle-file "No candle file present")
  73      (:in-progress "In progress"))
  74     (format nil "~{~A/~A/~A ~A:~A~}"
  75      (utils:time-as-list (third branch-info) :month :date :year :hr :min))))
  76   (sort (communication:query `(candle:project-branch-information ,name)) #'< :key #'third)))
  77
  78 (defun refresh-project (name)
  79  (communication:query `(candle:refresh-project ,name))
  80  (format t "Refreshed project ~A~%" name))
  81
  82 (defmethod execute-command ((command (eql :project)) args)
  83  (multiple-value-bind (options remaining-args error) (opera:process-arguments (project-options) args)
  84   (cond
  85    ((eql error :unknown-option) (format *error-output* "Unknown option: ~A.  See 'candle project --help'.~%" (car remaining-args)))
  86    ((eql error :required-argument-missing) (format *error-output* "Missing argument for ~A.  See 'candle project --help'.~%" (car remaining-args)))
  87    ((opera:option-present :help options) (format t "~A" (opera:usage "candle project" (project-options))))
  88    ((opera:option-present :delete options) (delete-project (opera:option-argument :delete options)))
  89    ((opera:option-present :show options) (show-project (opera:option-argument :show options)))
  90    ((opera:option-present :refresh options) (refresh-project (opera:option-argument :refresh options)))
  91    ((opera:option-present :add options) (add-project (opera:option-argument :add options))))))
  92
  93 (defmethod execute-command ((command (eql :job)) args)
  94  (multiple-value-bind (options remaining-args error) (opera:process-arguments (job-options) args)
  95   (cond
  96    ((eql error :unknown-option) (format *error-output* "Unknown option: ~A.  See 'candle job --help'.~%" (car remaining-args)))
  97    ((eql error :required-argument-missing) (format *error-output* "Missing argument for ~A.  See 'candle job --help'.~%" (car remaining-args)))
  98    ((opera:option-present :help options) (format t "~A" (opera:usage "candle job" (job-options)))))))
  99
 100 (defmethod execute-command ((command (eql :run)) args)
 101  (multiple-value-bind (options remaining-args error) (opera:process-arguments (run-options) args)
 102   (cond
 103    ((eql error :unknown-option) (format *error-output* "Unknown option: ~A.  See 'candle run --help'.~%" (car remaining-args)))
 104    ((eql error :required-argument-missing) (format *error-output* "Missing argument for ~A.  See 'candle run --help'.~%" (car remaining-args)))
 105    (remaining-args (format *error-output* "Unknown option: ~A. See 'candle run --help'.~%" (car remaining-args)))
 106    ((opera:option-present :help options) (format t "~A" (opera:usage "candle run" (run-options))))
 107    ((not (candle:run)) (sb-ext:exit :code 1)))))
 108
 109 (defun run ()
 110  (multiple-value-bind (options remaining-args error) (opera:process-arguments (main-options) (cdr sb-ext:*posix-argv*))
 111   (cond
 112    ((opera:option-present :help options) (main-usage))
 113    ((eql error :unknown-option) (format *error-output* "Unknown option: ~A.  See 'candle --help'.~%" (car remaining-args)))
 114    ((and (opera:option-present :port options) (not (parse-integer (opera:option-argument :port options) :junk-allowed t)))
 115     (format *error-output* "--port requires a number.  See 'candle-server -h'~%"))
 116    ((not remaining-args) (format *error-output* "Command required.  See 'candle --help'.~%"))
 117    (t
 118     (let
 119      ((communication:*query-port*
 120        (or
 121         (and
 122          (opera:option-present :port options)
 123          (parse-integer (opera:option-argument :port options) :junk-allowed t))
 124         25004)))
 125      (execute-command (intern (string-upcase (car remaining-args)) :keyword) (cdr remaining-args)))))))